Here's the 88 version of Resinoid - a dual-clear with a paper/imp which performs well against most opponents. It has a decent score vs the
Koenigstuhl top 50, losing by a small margin to approx 10 warriors:

Name Author %W %L %T Score ___________________________________________________________________
Sting John Metcalf 50 40 10 159.0
Ice Dragon John Metcalf 32 24 44 138.8
Monolith inversed 37 37 25 137.5
Night of the Living Dea John Metcalf 28 24 47 132.5
Copper Sputterer Christian Schmidt 27 23 50 132.2
Positive Knife '88 Ken Espiritu 24 17 59 130.4
Infiltrator inversed 29 29 42 129.2
Nemesis John Metcalf 24 23 53 125.4
Sorcery John Metcalf 23 22 55 124.0
Eye of the Storm John Metcalf 22 20 58 123.3
Utterer '88 Christian Schmidt 17 13 70 121.1
Triangular Sun inversed 17 15 68 118.8

The clear is based on Gymnosperm Trickery evolved by Dave Hillis:

* https://users.obs.carnegiescience.edu/birk/COREWAR/88/HILL32/ gymnospermtrickery.red

;redcode
;name Resinoid
;author John Metcalf
;strategy dual resin with paper/imps
;assert CORESIZE==8000

qfirst equ (qp2+2*qstep)
qdist equ qfirst+125
qstep equ 250

qi equ 7
qr equ 7

qbomb dat <qi/2-qi*qr, <qi*qr-qi/2

qa equ qstep*16
qb equ qstep*5+2
qc equ qstep*10
qd equ qstep*2
qe equ qstep*1

qgo cmp qdist+qc, qfirst+qc
jmp qfast, <qa
cmp qdist+qe+qd, qfirst+qe+qd
qp1 jmp <qfast, <qc
qp2 cmp qdist, qfirst
qp3 jmp qskip, <qe

cmp qdist+qb, qfirst+qb
q1 djn qfast, #qp1

cmp qdist+qd+qc, qfirst+qd+qc
jmp qslow, <qfirst+qd+qc+4
cmp qdist+qd+qb, qfirst+qd+qb
x1 jmp qslow, <q1
cmp qdist+qc+qc, qfirst+qc+qc
q2 djn qslow, #qp2
cmp qdist+qd, qfirst+qd
jmp qslow, <qfast
cmp qdist+qa, qfirst+qa
jmp q1, <q1

cmp qdist+qa+qd, qfirst+qa+qd
jmp x1, <q1
cmp qdist+qc+qb, qfirst+qc+qb
jmp q2, <q1
cmp qdist+qe+qd+qc,qfirst+qe+qd+qc
jmp qslower, <qfirst+qe+qd+qc+4
cmp qdist+qe+qd+qb,qfirst+qe+qd+qb
jmp qslower, <q1
cmp qdist+qe+qc+qc,qfirst+qe+qc+qc
jmp qslower, <q2
cmp qdist+qd+qd+qc,qfirst+qd+qd+qc
q3 djn qslower, #qp3
cmp qdist+qe+qc, qfirst+qe+qc
jmp <qfast, <q2
cmp qdist+qd+qd, qfirst+qd+qd
jmp <qfast, <q3
cmp qdist+qd+qd+qb,qfirst+qd+qd+qb
slt <q3, <q1

jmz warr, qdist+qe+qd+qc+10

qslower add @q3, @qslow
qslow add @q2, qkil
qfast add @q1, @qslow

qskip cmp <qdist+qstep+50, @qkil
jmp qloop, <1234

add #qdist-qfirst, qkil
qloop mov qbomb, @qkil
qkil mov <qfirst+qstep+50, <qfirst
sub #qi, @qloop
djn qloop, #qr+2

bpos equ resin+1300

warr spl 2, resin+6
spl 1, resin+6
spl 1, paper+6

mov <warr, <cboot1
mov <warr+1, <cboot2
mov <warr+2, <pboot

cboot1 spl @0, bpos+4000
cboot2 spl @0, bpos
pboot jmp @0, bpos-3800

; paper/imps

pstep equ 1085
istep equ 2667

size equ 6

paper mov <size, <papa
papa spl @0, pstep+size
spl 0, <4000
spl istep+1, <4000+istep
mov -1, istep
imp mov 0, istep

; clear inspired by GT

resin spl 0, <resin-100
spl 0, <resin-100
clear mov 1, <1
mov <0, <3321
djn clear, <resin-100

end qgo

--- SoupGate-Win32 v1.05
* Origin: fsxNet Usenet Gateway (21:1/5)