Inspired by <
https://arbitrarilyclose.com/2020/03/29/mathartchallenge-day-14-hitomezashi-stitching-suggested-by-katherine-seaton/>
I made this:
http://balglaas.sdf.org/hitomezashi/hitomezashi.html
and the basic version below.
See also this:
https://www.youtube.com/watch?v=JbfhzlMk2eY
=== 8< ==================================================
10 REM Hitomezashi
20 LET l=5
30 LET w=240
40 LET h=150
50 RANDOMIZE
60 REM === Kader =========
70 PLOT 0,0
80 DRAW w+l,0
90 DRAW 0,h+l
100 DRAW -(w+l),0
110 DRAW 0,-(h+l)
120 REM === Verticaal =====
130 LET i=1
140 GO SUB 370
150 LET j=0
160 IF dp=0 THEN GO TO 190
170 PLOT l*i,l*j
180 DRAW 0,l
190 LET dp=1-dp
200 LET j=j+1
210 IF j*l<=h THEN GO TO 160
220 LET i=i+1
230 IF i*l<=w THEN GO TO 140
240 REM === Horizontaal ===
250 LET j=1
260 GO SUB 370
270 LET i=0
280 IF dp=0 THEN GO TO 310
290 PLOT l*i,l*j
300 DRAW l,0
310 LET dp=1-dp
320 LET i=i+1
330 IF i*l<=w THEN GO TO 280
340 LET j=j+1
350 IF j*l<=h THEN GO TO 260
360 STOP
370 REM === Startpunt =====
380 LET dp=INT (2*RND)
390 RETURN
=== 8< ==================================================
--
Jan van den Broek
balglaas@xs4all.nl
Entertaining Quakers since 2005
--- SoupGate-Win32 v1.05
* Origin: fsxNet Usenet Gateway (21:1/5)