XPost: alt.comp.microsoft.windows
On 3/23/2023 3:31 PM, Paul wrote:
On 3/23/2023 2:31 PM, Maxmillian wrote:
I have two long lists of email addresses in Windows 10 as text files.
How can I lowercase everything and then get a diff of what email
addresses are in one text file but not in the other text file?
**************************** diffemail2.awk **************************
# Assumes file1.txt and file2.txt are in the current working directory
#
# .\gawk.exe -f diffemail2.awk file1.txt file2.txt common-out.txt
# ARGV[0] ARGV[1] ARGV[2] ARGV[3]
# ARGC=4
# normally, you would clear arguments before proceeding to read ( clear ARGV[3] )
BEGIN {
duplicates=0 # Your input is bad. Sanitize and retry. When bad, variable set to 1.
lines1=0 # count number of lines in file1 (to tell main loop, which input file we're in)
lines2=0 # malformed line number counter for file2
pass2 =0 # count number of lines of file1.txt and file2.txt processed in main loop
abend=1 # Set back to 0 if everything was OK
if ( ARGC != 4 ) {
print "Summary: gawk.exe -f diffemail2.awk file1.txt file2.txt common-out.txt"
exit(1)
}
file1=ARGV[1]
file2=ARGV[2]
output=ARGV[3]
# ARGV[1]="" # Zero out the args if you're not using them as input files
# ARGV[2]="" # Zero out the args if you're not using them as input files
ARGV[3]="" # Zero out the args if you're not using them as input files
while ( (getline < file1 ) > 0 ) { # load one file into memory
lines1++ # Figure out which file is being processed via line count
$0 = tolower($0)
if (length($0) > 0) { # don't process empty lines
if (NF != 1) { # an email address has no spaces in it, so only 1 string is present
printf("%s entry \"%s\" is malformed at line number %d\n", file1, $0, lines1)
duplicates=1
}
a[$0]++ # The array index is the key, array content currently dont matter much
if (a[$0] > 1) {
printf("%s entry %s is a duplicate\n", file1, $0)
duplicates=1
}
}
}
close(file1)
while ( (getline < file2 ) > 0 ) { # load one file into memory
lines2++ # for lines which are malformed
$0 = tolower($0)
if (length($0) > 0) {
if (NF != 1) {
printf("%s entry \"%s\" is malformed at line number %d\n", file2, $0, lines2)
duplicates=1
}
b[$0]++ # The array index is the key, array content currently dont matter much
if (b[$0] > 1) {
printf("%s entry %s is a duplicate\n", file2, $0)
duplicates=1
}
}
}
close(file2)
if (duplicates == 1) {
abend=1
exit(1) # don't execute main body or generate common-out.txt
} else { abend=0 }
}
{ # read file1.txt and file2.txt as "regular" input passed on command line
if (length($0) > 0) {
$0 = tolower($0)
if (pass2 < lines1) { # check whether entry from file1 is in file2
if ( ($0 in b) == 0 ) { printf("%s entry %s is not in file %s\n", file1, $0, file2 ) }
else { print $0 > output } # common-out.txt scans file1 items found in file2
} else { # check entry from file2 is in file1
if ( ($0 in a) == 0 ) { printf("%s entry %s is not in file %s\n", file2, $0, file1 ) }
}
}
pass2++ # increment lines processed on second pass,
# tells whether file1 or file2 is being processed, via the less-than check
}
END {
close( output )
print ""
if (abend == 0) { # Indicate normal run, if there was no obvious error
print "Check \"" output "\" for all email addresses common to both files"
}
}
**************************** END diffemail2.awk **************************
file1.txt
abc@not.in.computer
fOo@computer.com
baR@computer.com
bAz@computer.com
abc@not.in.computer <=== remove duplicate entry, then retry
Bad input <=== remove things which are not an email address, retry
<=== empty lines are tolerated
file2.txt
not@in.computer
foO@computer.com
Bar@computer.com
Baz@computer.com
not@in.computer <=== remove duplicate entry, then retry
bad input <=== remove things which are not an email address, retry
Output from first run.
.\gawk.exe -f diffemail2.awk file1.txt file2.txt common-out.txt
file1.txt entry
abc@not.in.computer is a duplicate
file1.txt entry "bad input" is malformed at line number 6
file2.txt entry
not@in.computer is a duplicate
file2.txt entry "bad input" is malformed at line number 6
Output from second run.
.\gawk.exe -f diffemail2.awk file1.txt file2.txt common-out.txt
file1.txt entry
abc@not.in.computer is not in file file2.txt
file2.txt entry
not@in.computer is not in file file1.txt
Check "common-out.txt" for all email addresses common to both files
The common-out.txt file looks like this:
foo@computer.com
bar@computer.com
baz@computer.com
Paul
--- SoupGate-Win32 v1.05
* Origin: fsxNet Usenet Gateway (21:1/5)